Apache2::CmdParms - Perl API for Apache command parameters object

NAME

Apache2::CmdParms - Perl API for Apache command parameters object

Synopsis

  use Apache2::CmdParms ();
  use Apache2::Module ();
  use Apache2::Const -compile => qw(NOT_IN_LOCATION);
  
  my @directives = (
    {
      name => 'MyDirective',
      cmd_data => 'some extra data',
    },
  );
  
  Apache2::Module::add(__PACKAGE__, \@directives);
  
  sub MyDirective {
      my($self, $parms, $args) = @_;
  
      # push config
      $parms->add_config(['ServerTokens off']);
  
      # this command's command object
      $cmd = $parms->cmd;
  
      # check the current command's context
      $error = $parms->check_cmd_context(Apache2::Const::NOT_IN_LOCATION);
  
      # this command's context
      $context = $parms->context;
  
      # this command's directive object
      $directive = $parms->directive;
  
      # the extra information passed thru cmd_data to
      # Apache2::Module::add()
      $info = $parms->info;
  
      # which methods are <Limit>ed ?
      $is_limited = $parms->method_is_limited('GET');
  
      # which allow-override bits are set
      $override = $parms->override;
  
      # the path this command is being invoked in
      $path = $parms->path;
  
      # this command's pool
      $p = $parms->pool;
  
      # this command's configuration time pool
      $p = $parms->temp_pool;
  }

Description

Apache2::CmdParms provides the Perl API for Apache command parameters object.

API

Apache2::CmdParms provides the following functions and/or methods:

add_config

Dynamically add Apache configuration at request processing runtime:

  $parms->add_config($lines);
obj: $parms ( Apache2::CmdParms object|docs::2.0::api::Apache2::CmdParms )
arg1: $lines (ARRAY ref)
An ARRAY reference containing configuration lines per element, without the new line terminators.

ret: no return value
since: 1.99_17

See also: $s->add_config|docs::2.0::api::Apache2::ServerUtil/C_add_config_, $r->add_config|docs::2.0::api::Apache2::RequestUtil/C_add_config_

check_cmd_context

Check the current command against a context bitmask of forbidden contexts.

  $error = $parms->check_cmd_context($check);
obj: $parms ( Apache2::CmdParms object|docs::2.0::api::Apache2::CmdParms )
arg1: $check ( Apache2::Const :context constant|docs::2.0::api::Apache2::Const/C__context_> )
the context to check against.

ret: $error ( string / undef )
If the context is forbidden, this method returns a textual description of why it was forbidden. If the context is permitted, this method returns undef.

since: 1.99_15

For example here is how to check whether a command is allowed in the <Location> container:

  use Apache2::Const -compile qw(NOT_IN_LOCATION);
  if (my $error = $parms->check_cmd_context(Apache2::Const::NOT_IN_LOCATION)) {
      die "directive ... not allowed in <Location> context"
  }

cmd

This module's command information

  $cmd = $parms->cmd();
obj: $parms ( Apache2::CmdParms object|docs::2.0::api::Apache2::CmdParms )
ret: $cmd ( Apache2::Command object|docs::2.0::api::Apache2::Command )
since: 1.99_17

directive

This command's directive object in the configuration tree

  $directive = $parms->directive;
obj: $parms ( Apache2::CmdParms object|docs::2.0::api::Apache2::CmdParms )
ret: $directive ( Apache2::Directive object|docs::2.0::api::Apache2::Directive )
The current directive node in the configuration tree

since: 1.99_12

info

The extra information passed through cmd_data in Apache2::Module::add()|docs::2.0::api::Apache2::Module/C_add_.

  $info = $parms->info;
obj: $parms ( Apache2::CmdParms object|docs::2.0::api::Apache2::CmdParms )
ret: $info ( string )
The string passed in cmd_data

since: 1.99_12

For example here is how to pass arbitrary information to a directive subroutine:

  my @directives = (
    {
      name => 'MyDirective1',
      func => \&MyDirective,
      cmd_data => 'One',
    },
    {
      name => 'MyDirective2',
      func => \&MyDirective,
      cmd_data => 'Two',
    },
  );
  Apache2::Module::add(__PACKAGE__, \@directives);
  
  sub MyDirective {
    my($self, $parms, $args) = @_;
    my $info = $parms->info;
  }

In this example $info will either be 'One' or 'Two' depending on whether the directive was called as MyDirective1 or MyDirective2.

method_is_limited

Discover if a method is <Limit>ed in the current scope

  $is_limited = $parms->method_is_limited($method);
obj: $parms ( Apache2::CmdParms object|docs::2.0::api::Apache2::CmdParms )
arg1: $method (string)
The name of the method to check for

ret: $is_limited ( boolean )
since: 1.99_15

For example, to check if the GET method is being <Limit>ed in the current scope, do:

  if ($parms->method_is_limited('GET') {
      die "...";
  }

override

Which allow-override bits are set (AllowOverride directive)

  $override = $parms->override;
obj: $parms ( Apache2::CmdParms object|docs::2.0::api::Apache2::CmdParms )
ret: $override ( bitmask )
the allow-override bits bitmask, which can be tested against Apache2::Const :override constants|docs::2.0::api::Apache2::Const/C__override_>.

since: 1.99_12

For example to check that the AllowOverride's AuthConfig and FileInfo options are enabled for this command, do:

  use Apache2::Const -compile qw(:override);
  $wanted = Apache2::Const::OR_AUTHCFG | Apache2::Const::OR_FILEINFO;
  $masked = $parms->override & $wanted;
  unless ($wanted == $masked) {
      die "...";
  }

path

The current pathname/location/match of the block this command is in

  $path = $parms->path;
obj: $parms ( Apache2::CmdParms object|docs::2.0::api::Apache2::CmdParms )
ret: $path ( string / undef )
If configuring for a block like <Location>, <LocationMatch>, <Directory>, etc., the pathname part of that directive. Otherwise, undef is returned.

since: 1.99_12

For example for a container block:

  <Location /foo>
  ...
  </Location>

'/foo' will be returned.

pool

Pool associated with this command

  $p = $parms->pool;
obj: $parms ( Apache2::CmdParms object|docs::2.0::api::Apache2::CmdParms )
ret: $p ( APR::Pool object|docs::2.0::api::APR::Pool )
since: 1.99_12

server

The (vhost) server this command was defined in httpd.conf

  $s = $parms->server;
obj: $parms ( Apache2::CmdParms object|docs::2.0::api::Apache2::CmdParms )
ret: $s ( Apache2::Server object|docs::2.0::api::Apache2::ServerRec )
since: 1.99_12

temp_pool

Pool for scratch memory; persists during configuration, but destroyed before the first request is served.

  $temp_pool = $parms->temp_pool;
obj: $parms ( Apache2::CmdParms object|docs::2.0::api::Apache2::CmdParms )
ret: $temp_pool ( APR::Pool object|docs::2.0::api::APR::Pool )
since: 1.99_12

Most likely you shouldn't use this pool object, unless you know what you are doing. Use $parms->pool|/C_pool_ instead.

Unsupported API

Apache2::CmdParms also provides auto-generated Perl interface for a few other methods which aren't tested at the moment and therefore their API is a subject to change. These methods will be finalized later as a need arises. If you want to rely on any of the following methods please contact the the mod_perl development mailing list so we can help each other take the steps necessary to shift the method to an officially supported API.

context

Get context containing pointers to modules' per-dir config structures.

  $context = $parms->context;
obj: $parms ( Apache2::CmdParms object|docs::2.0::api::Apache2::CmdParms )
ret: $newval ( Apache2::ConfVector object|docs::2.0::api::Apache2::ConfVector )
Returns the commands' per-dir config structures

since: 1.99_12

See Also

mod_perl 2.0 documentation.

Copyright

mod_perl 2.0 and its core modules are copyrighted under The Apache Software License, Version 2.0.

Authors

The mod_perl development team and numerous contributors.

 Apache2::CmdParms - Perl API for Apache command parameters object