• NAME
• SYNOPSIS
• DESCRIPTION
• Calling Conventions
• Declaration Syntax
• METHOD GENERATOR TYPES
• scalar - Shared Accessor
• array - Shared Ref Accessor
• hash - Shared Ref Accessor
• SEE ALSO

NAME

Class::MakeMethods::Basic::Global - Basic shared methods

SYNOPSIS

  package MyObject;
  use Class::MakeMethods::Basic::Global (
    scalar => [ 'foo', 'bar' ],
    array => 'my_list',
    hash => 'my_index',
  );
  ....
  
  # Store and retrieve global values
  MyObject->foo('Foobar');
  print MyObject->foo();
  
  # All instances of your class access the same values
  $my_object->bar('Barbados'); 
  print $other_one->bar(); 
  
  # Array accessor
  MyObject->my_list(0 => 'Foozle', 1 => 'Bang!');
  print MyObject->my_list(1);
  
  # Hash accessor
  MyObject->my_index('broccoli' => 'Blah!', 'foo' => 'Fiddle');
  print MyObject->my_index('foo');

DESCRIPTION

The Basic::Global subclass of MakeMethods provides basic accessors for data shared by an entire class, sometimes called ``static'' or ``class data.''

Calling Conventions

When you use this package, the method names you provide as arguments cause subroutines to be generated and installed in your module.

See Calling Conventions in the Class::MakeMethods::Basic manpage for a summary, or USAGE in the Class::MakeMethods manpage for full details.

Declaration Syntax

To declare methods, pass in pairs of a method-type name followed by one or more method names. Valid method-type names for this package are listed in METHOD GENERATOR TYPES.

See Declaration Syntax in the Class::MakeMethods::Basic manpage for more syntax information.

METHOD GENERATOR TYPES

scalar - Shared Accessor

For each method name passed, uses a closure to generate a subroutine with the following characteristics:

May be called as a class method, or equivalently, on any object instance.
Stores a global value accessible only through this method.
If called without any arguments returns the current value.
If called with an argument, stores that as the value, and returns it,

Sample declaration and usage:

  package MyObject;
  use Class::MakeMethods::Basic::Hash (
    scalar => 'foo',
  );
  ...
  
  # Store value
  MyObject->foo('Foozle');
  
  # Retrieve value
  print MyObject->foo;

array - Shared Ref Accessor

For each method name passed, uses a closure to generate a subroutine with the following characteristics:

May be called as a class method, or equivalently, on any object instance.
Stores a global value accessible only through this method.
The value will be a reference to an array (or undef).
If called without any arguments, returns the current array-ref value (or undef).
If called with one argument, uses that argument as an index to retrieve from the referenced array, and returns that value (or undef). If the single argument is an array ref, then a slice of the referenced array is returned.
If called with a list of index-value pairs, stores the value at the given index in the referenced array. If the value was previously undefined, a new array is autovivified. The current value in each position will be overwritten, and later arguments with the same index will override earlier ones. Returns the current array-ref value.

Sample declaration and usage:

  package MyObject;
  use Class::MakeMethods::Basic::Hash (
    array => 'bar',
  );
  ...
  
  # Set values by position
  $obj->bar(0 => 'Foozle', 1 => 'Bang!');
  
  # Positions may be overwritten, and in any order
  $obj->bar(2 => 'And Mash', 1 => 'Blah!');
  
  # Retrieve value by position
  print $obj->bar(1);
  
  # Retrieve slice of values by position
  print join(', ', $obj->bar( [0, 2] ) );
  
  # Direct access to referenced array
  print scalar @{ $obj->bar() };
  
  # Reset the array contents to empty
  @{ $obj->bar() } = ();

hash - Shared Ref Accessor

For each method name passed, uses a closure to generate a subroutine with the following characteristics:

May be called as a class method, or equivalently, on any object instance.
Stores a global value accessible only through this method.
The value will be a reference to a hash (or undef).
If called without any arguments, returns the current hash-ref value (or undef).
If called with one argument, uses that argument as an index to retrieve from the referenced hash, and returns that value (or undef). If the single argument is an array ref, then a slice of the referenced hash is returned.
If called with a list of key-value pairs, stores the value under the given key in the referenced hash. If the value was previously undefined, a new hash is autovivified. The current value under each key will be overwritten, and later arguments with the same key will override earlier ones. Returns the current hash-ref value.

Sample declaration and usage:

  package MyObject;
  use Class::MakeMethods::Basic::Hash (
    hash => 'baz',
  );
  ...
  
  # Set values by key
  $obj->baz('foo' => 'Foozle', 'bar' => 'Bang!');
  
  # Values may be overwritten, and in any order
  $obj->baz('broccoli' => 'Blah!', 'foo' => 'Fiddle');
  
  # Retrieve value by key
  print $obj->baz('foo');
  
  # Retrieve slice of values by position
  print join(', ', $obj->baz( ['foo', 'bar'] ) );
  
  # Direct access to referenced hash
  print keys %{ $obj->baz() };
  
  # Reset the hash contents to empty
  @{ $obj->baz() } = ();

SEE ALSO

See the Class::MakeMethods manpage for general information about this distribution.

See the Class::MakeMethods::Basic manpage for more about this family of subclasses.