WWW::Mechanize - Handy web browsing in a Perl object

NAME

WWW::Mechanize - Handy web browsing in a Perl object

VERSION

Version 1.34

SYNOPSIS

WWW::Mechanize, or Mech for short, helps you automate interaction with a website. It supports performing a sequence of page fetches including following links and submitting forms. Each fetched page is parsed and its links and forms are extracted. A link or a form can be selected, form fields can be filled and the next page can be fetched. Mech also stores a history of the URLs you've visited, which can be queried and revisited.

    use WWW::Mechanize;
    my $mech = WWW::Mechanize->new();
    $mech->get( $url );
    $mech->follow_link( n => 3 );
    $mech->follow_link( text_regex => qr/download this/i );
    $mech->follow_link( url => 'http://host.com/index.html' );
    $mech->submit_form(
        form_number => 3,
        fields      => {
            username    => 'mungo',
            password    => 'lost-and-alone',
        }
    );
    $mech->submit_form(
        form_name => 'search',
        fields    => { query  => 'pot of gold', },
        button    => 'Search Now'
    );

Mech is well suited for use in testing web applications. If you use one of the Test::*, like the Test::HTML::Lint manpage modules, you can check the fetched content and use that as input to a test call.

    use Test::More;
    like( $mech->content(), qr/$expected/, "Got expected content" );

Each page fetch stores its URL in a history stack which you can traverse.

    $mech->back();

If you want finer control over your page fetching, you can use these methods. follow_link and submit_form are just high level wrappers around them.

    $mech->find_link( n => $number );
    $mech->form_number( $number );
    $mech->form_name( $name );
    $mech->field( $name, $value );
    $mech->set_fields( %field_values );
    $mech->set_visible( @criteria );
    $mech->click( $button );

the WWW::Mechanize manpage is a proper subclass of the LWP::UserAgent manpage and you can also use any of the LWP::UserAgent manpage's methods.

    $mech->add_header($name => $value);

Please note that Mech does NOT support JavaScript. Please check the FAQ in WWW::Mechanize::FAQ for more.

IMPORTANT LINKS

CONSTRUCTOR AND STARTUP

new()

Creates and returns a new WWW::Mechanize object, hereafter referred to as the ``agent''.

    my $mech = WWW::Mechanize->new()

The constructor for WWW::Mechanize overrides two of the parms to the LWP::UserAgent constructor:

    agent => 'WWW-Mechanize/#.##'
    cookie_jar => {}    # an empty, memory-only HTTP::Cookies object

You can override these overrides by passing parms to the constructor, as in:

    my $mech = WWW::Mechanize->new( agent => 'wonderbot 1.01' );

If you want none of the overhead of a cookie jar, or don't want your bot accepting cookies, you have to explicitly disallow it, like so:

    my $mech = WWW::Mechanize->new( cookie_jar => undef );

Here are the parms that WWW::Mechanize recognizes. These do not include parms that the LWP::UserAgent manpage recognizes.

$mech->agent_alias( $alias )

Sets the user agent string to the expanded version from a table of actual user strings. $alias can be one of the following:

then it will be replaced with a more interesting one. For instance,

    $mech->agent_alias( 'Windows IE 6' );

sets your User-Agent to

    Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1)

The list of valid aliases can be returned from known_agent_aliases(). The current list is:

known_agent_aliases()

Returns a list of all the agent aliases that Mech knows about.

PAGE-FETCHING METHODS

$mech->get( $uri )

Given a URL/URI, fetches it. Returns an the HTTP::Response manpage object. $uri can be a well-formed URL string, a the URI manpage object, or a the WWW::Mechanize::Link manpage object.

The results are stored internally in the agent object, but you don't know that. Just use the accessors listed below. Poking at the internals is deprecated and subject to change in the future.

get() is a well-behaved overloaded version of the method in the LWP::UserAgent manpage. This lets you do things like

    $mech->get( $uri, ':content_file' => $tempfile );

and you can rest assured that the parms will get filtered down appropriately.

NOTE: Because :content_file causes the page contents to be stored in a file instead of the response object, some Mech functions that expect it to be there won't work as expected. Use with caution.

$mech->put( $uri, content => $content )

PUTs $content to $uri. Returns an the HTTP::Response manpage object. $uri can be a well-formed URI string, a the URI manpage object, or a the WWW::Mechanize::Link manpage object.

$mech->reload()

Acts like the reload button in a browser: repeats the current request. The history (as per the back method) is not altered.

Returns the the HTTP::Response manpage object from the reload, or undef if there's no current request.

$mech->back()

The equivalent of hitting the ``back'' button in a browser. Returns to the previous page. Won't go back past the first page. (Really, what would it do if it could?)

STATUS METHODS

$mech->success()

Returns a boolean telling whether the last request was successful. If there hasn't been an operation yet, returns false.

This is a convenience function that wraps $mech->res->is_success.

$mech->uri()

Returns the current URI as a the URI manpage object. This object stringifies to the URI itself.

$mech->response() / $mech->res()

Return the current response as an the HTTP::Response manpage object.

Synonym for $mech->response()

$mech->status()

Returns the HTTP status code of the response.

$mech->ct()

Returns the content type of the response.

$mech->base()

Returns the base URI for the current response

$mech->forms()

When called in a list context, returns a list of the forms found in the last fetched page. In a scalar context, returns a reference to an array with those forms. The forms returned are all the HTML::Form manpage objects.

$mech->current_form()

Returns the current form as an the HTML::Form manpage object.

$mech->links()

When called in a list context, returns a list of the links found in the last fetched page. In a scalar context it returns a reference to an array with those links. Each link is a the WWW::Mechanize::Link manpage object.

$mech->is_html()

Returns true/false on whether our content is HTML, according to the HTTP headers.

$mech->title()

Returns the contents of the <TITLE> tag, as parsed by the HTML::HeadParser manpage. Returns undef if the content is not HTML.

CONTENT-HANDLING METHODS

$mech->content(...)

Returns the content that the mech uses internally for the last page fetched. Ordinarily this is the same as $mech->response()->content(), but this may differ for HTML documents if update_html is overloaded (in which case the value passed to the base-class implementation of same will be returned), and/or extra named arguments are passed to content():

$mech-content( format => 'text' ) >>
Returns a text-only version of the page, with all HTML markup stripped. This feature requires HTML::TreeBuilder to be installed, or a fatal error will be thrown.

$mech-content( base_href => [$base_href|undef] ) >>
Returns the HTML document, modified to contain a <base href="$base_href"> mark-up in the header. $base_href is $mech->base() if not specified. This is handy to pass the HTML to e.g. the HTML::Display manpage.

Passing arguments to content() if the current document is not HTML has no effect now (i.e. the return value is the same as $self->response()->content(). This may change in the future, but will likely be backwards-compatible when it does.

LINK METHODS

$mech->links

Lists all the links on the current page. Each link is a WWW::Mechanize::Link object. In list context, returns a list of all links. In scalar context, returns an array reference of all links.

$mech->follow_link(...)

Follows a specified link on the page. You specify the match to be found using the same parms that find_link() uses.

Here some examples:

Returns the result of the GET method (an HTTP::Response object) if a link was found. If the page has no links, or the specified link couldn't be found, returns undef.

$mech->find_link( ... )

Finds a link in the currently fetched page. It returns a the WWW::Mechanize::Link manpage object which describes the link. (You'll probably be most interested in the url() property.) If it fails to find a link it returns undef.

You can take the URL part and pass it to the get() method. If that's your plan, you might as well use the follow_link() method directly, since it does the get() for you automatically.

Note that <FRAME SRC="..."> tags are parsed out of the the HTML and treated as links so this method works with them.

You can select which link to find by passing in one or more of these key/value pairs:

If n is not specified, it defaults to 1. Therefore, if you don't specify any parms, this method defaults to finding the first link on the page.

Note that you can specify multiple text or URL parameters, which will be ANDed together. For example, to find the first link with text of ``News'' and with ``cnn.com'' in the URL, use:

    $mech->find_link( text => 'News', url_regex => qr/cnn\.com/ );

The return value is a reference to an array containing a the WWW::Mechanize::Link manpage object for every link in $self->content.

The links come from the following:

<A HREF=...>
<AREA HREF=...>
<FRAME SRC=...>
<IFRAME SRC=...>
<META CONTENT=...>

$mech->find_all_links( ... )

Returns all the links on the current page that match the criteria. The method for specifying link criteria is the same as in find_link(). Each of the links returned is a the WWW::Mechanize::Link manpage object.

In list context, find_all_links() returns a list of the links. Otherwise, it returns a reference to the list of links.

find_all_links() with no parameters returns all links in the page.

$mech->find_all_inputs( ... criteria ... )

find_all_inputs() returns an array of all the input controls in the current form whose properties match all of the regexes passed in. The controls returned are all descended from HTML::Form::Input.

If no criteria are passed, all inputs will be returned.

If there is no current page, there is no form on the current page, or there are no submit controls in the current form then the return will be an empty array.

You may use a regex or a literal string:

    # get all textarea controls whose names begin with "customer"
    my @customer_text_inputs =
        $mech->find_all_inputs( {
            type       => 'textarea',
            name_regex => qr/^customer/,
        }
    );
    # get all text or textarea controls called "customer"
    my @customer_text_inputs =
        $mech->find_all_inputs( {
            type_regex => qr/^(text|textarea)$/,
            name       => 'customer',
        }
    );

$mech->find_all_submits( ... criteria ... )

find_all_submits() does the same thing as find_all_inputs() except that it only returns controls that are submit controls, ignoring other types of input controls like text and checkboxes.

IMAGE METHODS

$mech->images

Lists all the images on the current page. Each image is a WWW::Mechanize::Image object. In list context, returns a list of all images. In scalar context, returns an array reference of all images.

$mech->find_image()

Finds an image in the current page. It returns a the WWW::Mechanize::Image manpage object which describes the image. If it fails to find an image it returns undef.

You can select which image to find by passing in one or more of these key/value pairs:

If n is not specified, it defaults to 1. Therefore, if you don't specify any parms, this method defaults to finding the first image on the page.

Note that you can specify multiple ALT or URL parameters, which will be ANDed together. For example, to find the first image with ALT text of ``News'' and with ``cnn.com'' in the URL, use:

    $mech->find_image( image => 'News', url_regex => qr/cnn\.com/ );

The return value is a reference to an array containing a the WWW::Mechanize::Image manpage object for every image in $self->content.

$mech->find_all_images( ... )

Returns all the images on the current page that match the criteria. The method for specifying image criteria is the same as in find_image(). Each of the images returned is a the WWW::Mechanize::Image manpage object.

In list context, find_all_images() returns a list of the images. Otherwise, it returns a reference to the list of images.

find_all_images() with no parameters returns all images in the page.

FORM METHODS

$mech->forms

Lists all the forms on the current page. Each form is an the HTML::Form manpage object. In list context, returns a list of all forms. In scalar context, returns an array reference of all forms.

$mech->form_number($number)

Selects the numberth form on the page as the target for subsequent calls to field() and click(). Also returns the form that was selected.

If it is found, the form is returned as an the HTML::Form manpage object and set internally for later use with Mech's form methods such as field() and click().

Emits a warning and returns undef if no form is found.

The first form is number 1, not zero.

$mech->form_name( $name )

Selects a form by name. If there is more than one form on the page with that name, then the first one is used, and a warning is generated.

If it is found, the form is returned as an the HTML::Form manpage object and set internally for later use with Mech's form methods such as field() and click().

Returns undef if no form is found.

Note that this functionality requires libwww-perl 5.69 or higher.

$mech->form_with_fields( @fields )

Selects a form by passing in a list of field names it must contain. If there is more than one form on the page with that matches, then the first one is used, and a warning is generated.

If it is found, the form is returned as an the HTML::Form manpage object and set internally for later used with Mech's form methods such as field() and click().

Returns undef if no form is found.

Note that this functionality requires libwww-perl 5.69 or higher.

$mech->field( $name, $value, $number )

$mech->field( $name, \@values, $number )

Given the name of a field, set its value to the value specified. This applies to the current form (as set by the form_name() or form_number() method or defaulting to the first form on the page).

The optional $number parameter is used to distinguish between two fields with the same name. The fields are numbered from 1.

$mech->select($name, $value)

$mech->select($name, \@values)

Given the name of a select field, set its value to the value specified. If the field is not <select multiple> and the $value is an array, only the first value will be set. [Note: the documentation previously claimed that only the last value would be set, but this was incorrect.] Passing $value as a hash with an n key selects an item by number (e.g. {n = 3> or {n = [2,4]}>). The numbering starts at 1. This applies to the current form.

Returns 1 on successfully setting the value. On failure, returns undef and calls $self>warn() with an error message.

$mech->set_fields( $name => $value ... )

This method sets multiple fields of the current form. It takes a list of field name and value pairs. If there is more than one field with the same name, the first one found is set. If you want to select which of the duplicate field to set, use a value which is an anonymous array which has the field value and its number as the 2 elements.

        # set the second foo field
        $mech->set_fields( $name => [ 'foo', 2 ] ) ;

The fields are numbered from 1.

This applies to the current form.

$mech->set_visible( @criteria )

This method sets fields of the current form without having to know their names. So if you have a login screen that wants a username and password, you do not have to fetch the form and inspect the source (or use the mech-dump utility, installed with WWW::Mechanize) to see what the field names are; you can just say

    $mech->set_visible( $username, $password ) ;

and the first and second fields will be set accordingly. The method is called set_visible because it acts only on visible fields; hidden form inputs are not considered. The order of the fields is the order in which they appear in the HTML source which is nearly always the order anyone viewing the page would think they are in, but some creative work with tables could change that; caveat user.

Each element in @criteria is either a field value or a field specifier. A field value is a scalar. A field specifier allows you to specify the type of input field you want to set and is denoted with an arrayref containing two elements. So you could specify the first radio button with

    $mech->set_visible( [ radio => 'KCRW' ] ) ;

Field values and specifiers can be intermixed, hence

    $mech->set_visible( 'fred', 'secret', [ option => 'Checking' ] ) ;

would set the first two fields to ``fred'' and ``secret'', and the next OPTION menu field to ``Checking''.

The possible field specifier types are: ``text'', ``password'', ``hidden'', ``textarea'', ``file'', ``image'', ``submit'', ``radio'', ``checkbox'' and ``option''.

set_visible returns the number of values set.

$mech->tick( $name, $value [, $set] )

``Ticks'' the first checkbox that has both the name and value associated with it on the current form. Dies if there is no named check box for that value. Passing in a false value as the third optional argument will cause the checkbox to be unticked.

$mech->untick($name, $value)

Causes the checkbox to be unticked. Shorthand for tick($name,$value,undef)

$mech->value( $name, $number )

Given the name of a field, return its value. This applies to the current form.

The option $number parameter is used to distinguish between two fields with the same name. The fields are numbered from 1.

If the field is of type file (file upload field), the value is always cleared to prevent remote sites from downloading your local files. To upload a file, specify its file name explicitly.

$mech->click( $button [, $x, $y] )

Has the effect of clicking a button on the current form. The first argument is the name of the button to be clicked. The second and third arguments (optional) allow you to specify the (x,y) coordinates of the click.

If there is only one button on the form, $mech->click() with no arguments simply clicks that one button.

Returns an the HTTP::Response manpage object.

$mech->click_button( ... )

Has the effect of clicking a button on the current form by specifying its name, value, or index. Its arguments are a list of key/value pairs. Only one of name, number, input or value must be specified in the keys.

$mech->submit()

Submits the page, without specifying a button to click. Actually, no button is clicked at all.

Returns an the HTTP::Response manpage object.

This used to be a synonym for $mech->click( 'submit' ), but is no longer so.

$mech->submit_form( ... )

This method lets you select a form from the previously fetched page, fill in its fields, and submit it. It combines the form_number/form_name, set_fields and click methods into one higher level call. Its arguments are a list of key/value pairs, all of which are optional.

If no form is selected, the first form found is used.

If button is not passed, then the submit() method is used instead.

Returns an the HTTP::Response manpage object.

MISCELLANEOUS METHODS

$mech->add_header( name => $value [, name => $value... ] )

Sets HTTP headers for the agent to add or remove from the HTTP request.

    $mech->add_header( Encoding => 'text/klingon' );

If a value is undef, then that header will be removed from any future requests. For example, to never send a Referer header:

    $mech->add_header( Referer => undef );

If you want to delete a header, use delete_header.

Returns the number of name/value pairs added.

NOTE: This method was very different in WWW::Mechanize before 1.00. Back then, the headers were stored in a package hash, not as a member of the object instance. Calling add_header() would modify the headers for every WWW::Mechanize object, even after your object no longer existed.

$mech->delete_header( name [, name ... ] )

Removes HTTP headers from the agent's list of special headers. For instance, you might need to do something like:

    # Don't send a Referer for this URL
    $mech->add_header( Referer => undef );
    # Get the URL
    $mech->get( $url );
    # Back to the default behavior
    $mech->delete_header( 'Referer' );

$mech->quiet(true/false)

Allows you to suppress warnings to the screen.

    $mech->quiet(0); # turns on warnings (the default)
    $mech->quiet(1); # turns off warnings
    $mech->quiet();  # returns the current quietness status

$mech->stack_depth( $max_depth )

Get or set the page stack depth. Use this if you're doing a lot of page scraping and running out of memory.

A value of 0 means ``no history at all.'' By default, the max stack depth is humongously large, effectively keeping all history.

$mech->save_content( $filename )

Dumps the contents of $mech->content into $filename. $filename will be overwritten. Dies if there are any errors.

$mech->dump_links( [[$fh], $absolute] )

Prints a dump of the links on the current page to $fh. If $fh is not specified or is undef, it dumps to STDOUT.

If $absolute is true, links displayed are absolute, not relative.

$mech->dump_images( [[$fh], $absolute] )

Prints a dump of the images on the current page to $fh. If $fh is not specified or is undef, it dumps to STDOUT.

If $absolute is true, links displayed are absolute, not relative.

$mech->dump_forms( [$fh] )

Prints a dump of the forms on the current page to $fh. If $fh is not specified or is undef, it dumps to STDOUT.

$mech->dump_all( [[$fh], $absolute] )

Prints a dump of all links, images and forms on the current page to $fh. If $fh is not specified or is undef, it dumps to STDOUT.

If $absolute is true, links displayed are absolute, not relative.

OVERRIDDEN LWP::UserAgent METHODS

$mech->clone()

Clone the mech object. We override here to be sure the cookie jar gets copied over

$mech->redirect_ok()

An overloaded version of redirect_ok() in the LWP::UserAgent manpage. This method is used to determine whether a redirection in the request should be followed.

$mech->request( $request [, $arg [, $size]])

Overloaded version of request() in the LWP::UserAgent manpage. Performs the actual request. Normally, if you're using WWW::Mechanize, it's because you don't want to deal with this level of stuff anyway.

Note that $request will be modified.

Returns an the HTTP::Response manpage object.

$mech->update_html( $html )

Allows you to replace the HTML that the mech has found. Updates the forms and links parse-trees that the mech uses internally.

Say you have a page that you know has malformed output, and you want to update it so the links come out correctly:

    my $html = $mech->content;
    $html =~ s[</option>.{0,3}</td>][</option></select></td>]isg;
    $mech->update_html( $html );

This method is also used internally by the mech itself to update its own HTML content when loading a page. This means that if you would like to systematically perform the above HTML substitution, you would overload update_html in a subclass thusly:

   package MyMech;
   use base 'WWW::Mechanize';
   sub update_html {
       my ($self, $html) = @_;
       $html =~ s[</option>.{0,3}</td>][</option></select></td>]isg;
       $self->WWW::Mechanize::update_html( $html );
   }

If you do this, then the mech will use the tidied-up HTML instead of the original both when parsing for its own needs, and for returning to you through content.

Overloading this method is also the recommended way of implementing extra validation steps (e.g. link checkers) for every HTML page received. warn and die would then come in handy to signal validation errors.

$mech->credentials( $username, $password )

Provide credentials to be used for HTTP Basic authentication for all sites and realms until further notice.

The four argument form described in the LWP::UserAgent manpage is still supported.

INTERNAL-ONLY METHODS

These methods are only used internally. You probably don't need to know about them.

$mech->_update_page($request, $response)

Updates all internal variables in $mech as if $request was just performed, and returns $response. The page stack is not altered by this method, it is up to caller (e.g. request) to do that.

$mech->_modify_request( $req )

Modifies a the HTTP::Request manpage before the request is sent out, for both GET and POST requests.

We add a Referer header, as well as header to note that we can accept gzip encoded content, if the Compress::Zlib manpage is installed.

$mech->_make_request()

Convenience method to make it easier for subclasses like the WWW::Mechanize::Cached manpage to intercept the request.

$mech->_reset_page()

Resets the internal fields that track page parsed stuff.

$mech->_extract_links()

Extracts links from the content of a webpage, and populates the {links} property with the WWW::Mechanize::Link manpage objects.

$mech->_push_page_stack() / $mech->_pop_page_stack()

The agent keeps a stack of visited pages, which it can pop when it needs to go BACK and so on.

The current page needs to be pushed onto the stack before we get a new page, and the stack needs to be popped when BACK occurs.

Neither of these take any arguments, they just operate on the $mech object.

warn( @messages )

Centralized warning method, for diagnostics and non-fatal problems. Defaults to calling CORE::warn, but may be overridden by setting onwarn in the constructor.

die( @messages )

Centralized error method. Defaults to calling CORE::die, but may be overridden by setting onerror in the constructor.

REQUESTS & BUGS

The bug queue for WWW::Mechanize and Test::WWW::Mechanize is at http://code.google.com/p/www-mechanize/issues/list. Please do not add any tickets to the old queue at http://rt.cpan.org/.

WWW::MECHANIZE'S SUBVERSION REPOSITORY

Mech and Test::WWW::Mechanize are both hosted at Google Code: http://code.google.com/p/www-mechanize/. The Subversion repository is at http://www-mechanize.googlecode.com/svn/wm/.

OTHER DOCUMENTATION

Spidering Hacks, by Kevin Hemenway and Tara Calishain

Spidering Hacks from O'Reilly (http://www.oreilly.com/catalog/spiderhks/) is a great book for anyone wanting to know more about screen-scraping and spidering.

There are six hacks that use Mech or a Mech derivative:

#21 WWW::Mechanize 101
#22 Scraping with WWW::Mechanize
#36 Downloading Images from Webshots
#44 Archiving Yahoo! Groups Messages with WWW::Yahoo::Groups
#64 Super Author Searching
#73 Scraping TV Listings

The book was also positively reviewed on Slashdot: http://books.slashdot.org/article.pl

ONLINE RESOURCES AND SUPPORT

ARTICLES ABOUT WWW::MECHANIZE

Other modules that use Mechanize

Here are modules that use or subclass Mechanize. Let me know of any others:

ACKNOWLEDGEMENTS

Thanks to the numerous people who have helped out on WWW::Mechanize in one way or another, including Kirrily Robert for the original WWW::Automate, Adriano Ferreira, Miyagawa, Peteris Krumins, Rafael Kitover, David Steinbrunner, Kevin Falcone, Mike O'Regan, Mark Stosberg, Uri Guttman, Peter Scott, Phillipe Bruhat, Ian Langworth, John Beppu, Gavin Estey, Jim Brandt, Ask Bjoern Hansen, Greg Davies, Ed Silva, Mark-Jason Dominus, Autrijus Tang, Mark Fowler, Stuart Children, Max Maischein, Meng Wong, Prakash Kailasa, Abigail, Jan Pazdziora, Dominique Quatravaux, Scott Lanning, Rob Casey, Leland Johnson, Joshua Gatcomb, Julien Beasley, Abe Timmerman, Peter Stevens, Pete Krawczyk, Tad McClellan, and the late great Iain Truskett.

COPYRIGHT

Copyright (c) 2005-2007 Andy Lester. All rights reserved. This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

 WWW::Mechanize - Handy web browsing in a Perl object